I can't tell you anything about your Excel code, as I've done very
little of that. But if it gets your worksheet built the way you want,
that's fine. I haven't dug into  VSTO yet -- that's on my list of
things to do (somebody send me a 'tuit'!). And if you plan to use XML
and/or LINQ, be sure all your users will be on Office 2007; by
comparison, the Office 2003 implementation is clunky.

Here are some points about dealing with the Word document:

1. You can't add rows to the table while the document is protected.
The code must start by unprotecting the document. Then it can add
rows, add content such as form fields to the cells, and do any
formatting. At the end, it reprotects the document.

2. In the VB editor, click Tools > References and put a checkmark on
the Word Object Library. That will give you IntelliSense for objects
in the Word model and allow type checking.

3. It's sometimes necessary, and always a good idea, to qualify all
type names with the application that's intended. For example, both
Word and Excel  have Range objects, so you must qualify anything you
declare as a Range. Even when there's no ambiguity, it helps you when
you go back to do maintenance to know which application a particular
variable refers to.

4. If you're driving Word from an Excel macro, then I think neither
ADO nor DAO is appropriate. That would be for pulling data from Excel
(the server app) with a Word-based macro (the client). However, I'm
far from an expert on that.

I whomped up a little demonstration for you. I created a worksheet
with data in three columns (LastName, FirstName, and Salary) and about
a dozen rows, and set a named range ("Presidents") to cover all but
the title row. I also created a Word template named "Names.dotx" (this
is in Word 2007) that contains a table with only a header row of three
columns, and protected it for forms although it doesn't contain any
form fields. This Excel macro creates a new document in Word from the
template and then builds the table from the Excel data.

Sub demo()
   Dim wdApp As Word.Application
   Dim wdDoc As Word.Document
   Dim wdTbl As Word.Table
   Dim wdRow As Word.Row
   Dim xlRange As Excel.Range
   Dim xlRow As Excel.Range
   
   On Error Resume Next
   ' try to get Word if it's open already
   Set wdApp = GetObject(, "Word.Application")
   If Err.Number <> 0 Then
       Err.Clear
       On Error Resume Next
       Set wdApp = CreateObject("Word.Application")
   End If
   
   If Not wdApp Is Nothing Then
       wdApp.Visible = True
       Set wdDoc = wdApp.Documents.Add( _
           Template:="Names.dotx") ' <== change
   Else
       MsgBox "Could not create a Word document"
       Exit Sub
   End If
   
   If wdDoc.ProtectionType <> wdNoProtection Then
       wdDoc.Unprotect  ' optional password
   End If
   
   ' the template has a table (heading row only)
   ' so you know there is a .Tables(1)
   Set wdTbl = wdDoc.Tables(1)
   For Each xlRow In ActiveWorkbook.Names _
           ("Presidents").RefersToRange.Rows ' <== change
       Set wdRow = wdTbl.Rows.Add
       
       wdDoc.FormFields.Add Range:=wdRow.Cells(1).Range, _
           Type:=wdFieldFormTextInput
       wdRow.Cells(1).Range.FormFields(1).Result = _
           xlRow.Cells(1, 1).Value
       
       wdDoc.FormFields.Add Range:=wdRow.Cells(2).Range, _
           Type:=wdFieldFormTextInput
       wdRow.Cells(2).Range.FormFields(1).Result = _
           xlRow.Cells(1, 2).Value
       
       wdDoc.FormFields.Add Range:=wdRow.Cells(3).Range, _
           Type:=wdFieldFormTextInput
       wdRow.Cells(3).Range.FormFields(1).TextInput.EditType _
           Type:=wdNumberText, Format:="$#,##0.00"
       wdRow.Cells(3).Range.FormFields(1).Result = _
           xlRow.Cells(1, 3).Value
   Next
   
   wdDoc.Protect Type:=wdAllowOnlyFormFields, NoReset:=True
   wdDoc.Save
End Sub

This demo is a bit clumsy; it could use some cleanup and more error
checking, but it should point you in the right direction for a
VBA-only solution.

--
Regards,
Jay Freedman
Microsoft Word MVP        FAQ: http://word.mvps.org
Email cannot be acknowledged; please post all follow-ups to the newsgroup so all may benefit.

Hi Eric,

Another thing you'll have to deal with on the Word side, is unprotecting the document before populating the table, then reprotecting
the document again afterwards. Either that or you'll have to put the table in an unprotected Section of the document. That's because
the forms protection won't allow you to edit the protected portion of the document. Unprotecting & reprotecting the document is
fairly straightforward.

Since you're working with a document protected for forms, and you apparently want to import some data from an Excel workbook, have
you thought of using a LINK field and just updating the field's source range to suit the user's input in a given formfield?

Cheers