Mark was telling us:
Mark nous racontait que :

The problem with renaming is that at the first occurrence of a style that
the macro finds that must be renamed, it tries to apply a name that already
exists... No can do!

The other alternative would be to find each paragraph formatted with a Main
Text char style, apply the regular Main Text style, then just delete the
char styles.

That might be very slow...

Here is an alternative idea:

'_______________________________________
Sub Find_Replace_MainT()

Dim pIndex As Long
Dim MyStyle As Style
Const TempStyleName As String = "TempStyle"
Const RegularName As String = "Main Text"

'Save any paragraph where the Normal style is applied
With ActiveDocument
   .Styles.Add TempStyleName
   With Selection.Find
       .ClearFormatting
       .Style = ActiveDocument.Styles("Normal")
       .Text = ""
       .Forward = True
       .Wrap = wdFindContinue
       .Format = True
       With .Replacement
           .ClearFormatting
           .Style = ActiveDocument.Styles(TempStyleName)
           .Text = ""
       End With
       .Execute Replace:=wdReplaceAll
   End With

'Delete all Char styles derived from Main Text
'Paragraphs where a deleted style was applied will
'revert to the Normal style
   For pIndex = .Styles.Count To 1 Step -1
       Set MyStyle = .Styles(pIndex)
       With MyStyle
           If Left$(.NameLocal, 10) = RegularName & " " Then
               .Delete
           End If
       End With
   Next

'Apply Main Text to all Normal paragraphs
   With Selection.Find
       .ClearFormatting
       .Style = ActiveDocument.Styles("Normal")
       .Text = ""
       .Forward = True
       .Wrap = wdFindContinue
       .Format = True
       With .Replacement
           .ClearFormatting
           .Style = ActiveDocument.Styles(RegularName)
           .Text = ""
       End With
       .Execute Replace:=wdReplaceAll
   End With

'Delete the TEmnpStyle style and if any pargraph were formatteed
'with it, they will be returned to their original "Normal" style
   .Styles(TempStyleName).Delete

End With

End Sub
'_______________________________________

The drawback is that if lots of text had manually been "formatted" with the
Normal style, all those manual alterations to paragraph format will be lost,
the same to all manual formatting that had might have been applied to any
char style. Font formatting will be preserved.
I do not think this can be avoided when dealing with styles, short of
testing each paragraph, storing their paragraph formatting parameters,
changing the style, then reapplying the manual formatting. Very tedious and
the macro would run very slowly, I think.