Cathy D. was telling us:
Cathy D. nous racontait que :

THe cell marker is actually two character: Chr(13) and Chr(7).  YOu can test
this with this little macro:
'_______________________________________
Sub CellContent()

Dim CellText As String
Dim CelLen As Long

CellText = Selection.Range.Text

CelLen = Len(CellText)

For i = 1 To CelLen
   MsgBox "Character # " & i & " is " _
       & "Chr(" & Asc(Mid(CellText, i, 1)) & ")"
Next

End Sub
'_______________________________________

Select a cell and its content and run the macro. Choose one that has only a
few characters and that whose last one is a ?.

You notice that the last three characters are Chr(13) (the ?) and
Chr(13)+Chr(7) (the ?).
So you could write a macro to used VB string manipulation and test each cell
content, if you find Chr(13) Chr(13) Chr(7) , then remove the first Chr(13)
of the two. Or, you could use a little macro such as this one:

'_______________________________________
Sub RemoveLastParMark_in_Cell()

Dim CellRage As Range
Dim MyTable As Table
Dim MyCell As Cell

Application.ScreenUpdating = False

With ActiveDocument
   For Each MyTable In .Tables
       For Each MyCell In MyTable.Range.Cells
           Do While MyCell.Range.Characters.Last.Previous = Chr(13)
               MyCell.Range.Characters.Last.Previous.Delete
           Loop
       Next
   Next
End With

Application.ScreenRefresh
Application.ScreenUpdating = True

End Sub
'_______________________________________

I am sure someone will be along shortly with an even faster way of doing
this, but at the moment this all my little brain can concoct!

Cheers.