Julian,

I used this process:

Find all of the indexed words and add to an array.
Sort the array alphabelically
Add the contents of the sorted array to the ListBox

I created a UserForm and named it frmIndexEntries

Call the UserForm with something like this:

Sub CallUserForm()
Dim myFrm As frmIndexEntries
Set myFrm = New frmIndexEntries
myFrm.Show
Unload myFrm
Set myFrm = Nothing
End Sub

Here is the code for the UserForm (Note it is simply a listbox to list
the indexed items and a command button to hide the form)

Option Explicit
Const cNoValue = -2
Private Sub CommandButton1_Click()
Me.Hide
End Sub
Private Sub UserForm_Initialize()
Dim oField As Field
Dim tmpString As String
Dim MyArray() As String
Dim i As Long
Dim a As Integer
Dim z As Integer
i = -1
'Find all the index entries and put into an array
For Each oField In ActiveDocument.Fields
 If oField.Type = wdFieldIndexEntry Then
   i = i + 1
   tmpString = Mid(oField.Code.Text, 6)
   tmpString = Left(tmpString, InStr(tmpString, """") - 1)
   ReDim Preserve MyArray(i)
     MyArray(i) = tmpString
 End If
Next
'Sort array alphabetically
a = LBound(MyArray)
z = UBound(MyArray)
QuickSort MyArray, a, z
'Build the sorted ListBox
For i = 0 To UBound(MyArray)
 Me.ListBox1.AddItem (MyArray(i))
Next
End Sub
Public Sub QuickSort(MyArray As Variant, _
   Optional iLeft As Integer = cNoValue, _
   Optional iRight As Integer = cNoValue)

Dim iVarA As Integer
Dim iVarB As Integer
Dim vTest As Variant
Dim iMid As Integer

If iLeft = cNoValue Then iLeft = LBound(MyArray)
If iRight = cNoValue Then iRight = UBound(MyArray)
If iLeft < iRight Then
 iMid = (iLeft + iRight) \ 2
 vTest = MyArray(iMid)
 iVarA = iLeft
 iVarB = iRight
 Do
   Do While MyArray(iVarA) < vTest
     iVarA = iVarA + 1
   Loop
   Do While MyArray(iVarB) > vTest
     iVarB = iVarB - 1
   Loop
   If iVarA <= iVarB Then
     Swap MyArray, iVarA, iVarB
     iVarA = iVarA + 1
     iVarB = iVarB - 1
   End If
 Loop Until iVarA > iVarB
 If iVarB <= iMid Then
   Call QuickSort(MyArray, iLeft, iVarB)
   Call QuickSort(MyArray, iVarA, iRight)
 Else
   Call QuickSort(MyArray, iVarA, iRight)
   Call QuickSort(MyArray, iLeft, iVarB)
 End If
End If
End Sub
Private Sub Swap(vItems As Variant, iItem1 As Integer, _
                iItem2 As Integer)
Dim vTemp As Variant
vTemp = vItems(iItem2)
vItems(iItem2) = vItems(iItem1)
vItems(iItem1) = vTemp
End Sub

The challenge of course was to get the only the actual "word" text out
of the index entry field.  The rest of the sort and build stuff was
from a similiar project that Jay Freedman helped me with last year.

I am just a casual VBA user and so always welcome suggestions for
improvement on all I manage to cobble together.

HTH