This is a little more complicated than you might think at first. Not a lot,
just a little.

The first problem to work around is that you can't insert a picture at a
bookmark in a protected document while it's still protected. The code will
have to unprotect the document, insert the picture, and finally reprotect
the document (using an optional parameter of the .Protect method to prevent
all the fields from resetting to their default values).

The second thing isn't a problem, but a simplification. Since you'll be
using a table (with fixed column width) to hold the picture, you don't need
a bookmark to know where to put the picture. Also, it's poor practice to
move the insertion point and use the Selection object to insert the picture;
you can directly address the particular cell of the table without selecting
it.

As an example, add this to whatever other code is in your command button's
Click procedure:

   Const path = "C:\PROJECT\TEST1\IMAGES\"
   Dim oTbl As Table
   Dim oCel As Cell

   ' unprotect the form if needed
   If ActiveDocument.ProtectionType <> wdNoProtection Then
       ActiveDocument.Unprotect
   End If

   ' modify the next two lines if the table isn't the
   ' first one in the document, or if the signature
   ' goes in a different cell of the table
   Set oTbl = ActiveDocument.Tables(1)
   Set oCel = oTbl.Cell(1, 2)

   ' note the Range argument...
   ActiveDocument.InlineShapes.AddPicture _
       FileName:=path & TEST1.Fields("op_sign").Value & _
       ".jpg", LinkToFile:=False, SaveWithDocument:=True, _
       Range:=oCel.Range

   ' reprotect without resetting the fields to default values
   ActiveDocument.Protect Type:=wdAllowOnlyFormFields, _
       NoReset:=True