If all you want is display the autotext text (no formatting), then use a
textbox or a label and this code in the appropriate event:

With Me
   .Label1.Caption = NormalTemplate.AutoTextEntries("aero_header").Value
End With

But this will display field codes and other funny characters...
So, if you want to display field values instead of code, try this instead:

Dim rngAuto As Range

Set rngAuto = ActiveDocument.Range

With rngAuto
   .Collapse wdCollapseEnd
   .InsertAfter "aero_header"
   .InsertAutoText
End With

With Me
   .Label1.Caption = rngAuto.Text
End With

rngAuto.Delete

However, if you want to display the AutoText with the formatting, you will
need a RichTextBox control.
Add it to your Toolbox palette by right clicking on the control palette when
you are designing the userform. Check the "Microsoft RichTextBox COntrol 6.0"
in the list. It will be added to your palette. If, when you try to add it to
your userform, you get a trust message, then, in order to get your machine to
accept the ActiveX control, see the following post (it is about Excel, but it
still applies...)

http://groups.google.com/group/microsoft.public.office.developer.vba/browse_thre
ad/thread/3ef04a2f2a8cef1e/76252635e022bb41

After that, add the RichTextBox comntrol to you userform. Finally, at the
appropriate location in your code, use code like this:

Dim docAuto As Document
Dim rngAuto As Range

Set docAuto = Application.Documents.Add
Set rngAuto = docAuto.Range

With rngAuto
   .InsertAfter "AutoText_Name"
   .InsertAutoText
End With

docAuto.SaveAs "C:\My Documents\Test\TestAuto.rtf", wdFormatRTF
docAuto.Close

With Me
   .RichTextBox1.FileName = "C:\My Documents\Test\TestAuto.rtf"
End With

The only way I know of getting a RichText box to display the formatting, is
to feed it an RTF file. You can use this code over and over, the RTF file
gets re-written each time...