Hi Jim,

Taking your request literally, this macro will do what you asked:

Sub OpenNumberedDoc()
  Dim TheNumber As String

  On Error Resume Next
  TheNumber = InputBox$("Enter the doc number")
  If TheNumber <> "" Then
     Documents.Open FileName:= _
        "c:\MS Word Docs\" & TheNumber & ".doc"
  End If
End Sub

Thinking a bit sideways, though, you might be better off using the Work menu
(http://word.mvps.org/FAQs/General/WorkMenu.htm).

Jim,

Just assign something like the following to a toolbar icon:

Sub JimFileOpen()
Dim oDir As String
Dim oName As String
oDir = "C:\MS Word Docs\"
oName = InputBox("Type the file number:", "Enter Value")
Application.Documents.Open FileName:=oDir & oName & ".doc"
End Sub

Jim In Minneapolis was telling us:
Jim In Minneapolis nous racontait que :

Here is some code with basic error trapping to make sure there are no
"silly" errors...

Just change the path (Documents.Open... line) if necessary and the upper
limit number (Const UpperLim As... line) in the code.

'_______________________________________
Const UpperLim As Long = 30
'_______________________________________
Sub myOpenFile()

Dim MyFile As String

MyFile = ""

Do
   If MyFile <> "" Then
       'If we get in this If block,
       'This is a second pass because user did not type a valid number
       MsgBox "You must type a valid number (From 1 to " _
           & CStr(UpperLim) & ").", vbExclamation, "Try again"
   End If
   MyFile = GetNumber
   If MyFile = "" Then Exit Sub
Loop While CLng(MyFile) > UpperLim Or MyFile = 0

Documents.Open "C:\MS Word Docs\" & MyFile & ".doc"

End Sub
'_______________________________________

'_______________________________________
Function GetNumber() As String

GetNumber = ""

Do
   If GetNumber <> "" Then
       'If we get in this If block,
       'This is a second pass because user did not type a number
       MsgBox "You must type a number.", vbExclamation, "Try again"
   End If
   GetNumber = InputBox("What file number do you want to open?", "Open
File")
   If GetNumber = "" Then
       'User cancelled out of Inputbox or did not type anything
       MsgBox "You have not chosen a file number.", vbExclamation,
"Cancelling"
       Exit Function
   End If
Loop While Not IsNumeric(GetNumber)

End Function
'_______________________________________