What follows is a macro to unlink all fields in a document, cycling through
the storyranges. You should be able to adapt it to your use, incrementing a
variable with the fields.count from each story.

Sub FieldsUnlinkAllStory()
'   All Story Field Unlinker
'   Written by Charles Kyle Kenyon 9 December 2004
'   repaired with help from Jezebel 10 December 2004
   Dim oStory As Range
   On Error Resume Next
   For Each oStory In ActiveDocument.StoryRanges
       Do
           oStory.Fields.Unlink
           Set oStory = oStory.NextStoryRange
       Loop Until oStory Is Nothing
   Next
End Sub

Here's your fish:

Sub CountAllFields()
Dim pRange As Word.Range
Dim oFld As Field
Dim iLink As Long
Dim i As Long
Dim j As Long
Dim k As Long
Dim l As Long
iLink = ActiveDocument.Sections(1).Headers(1).Range.StoryType
For Each pRange In ActiveDocument.StoryRanges
 Do
   Select Case pRange.StoryType
     Case 1 'The Main text
       i = pRange.Fields.Count
     Case 6, 7, 10
       j = j + pRange.Fields.Count
     Case 8, 9, 11
       k = k + pRange.Fields.Count
     Case Else
       l = l + pRange.Fields.Count
   End Select
   Set pRange = pRange.NextStoryRange
 Loop Until pRange Is Nothing
Next
MsgBox "There are " & i & " fields in the main text."
MsgBox "There are " & j & " fields in the headers."
MsgBox "There are " & k & " fields in the footers."
MsgBox "There are " & l & " fields in the other places."
MsgBox "There are " & i + j + k + l & " fields total."
End Sub

Now that I have been duly sworn ,  it is chr(13) and chr(7).  Select an
empty cell and run the following code:

Sub Test()
MsgBox Asc(Selection.Text) _
 & " and " & Asc(Right(Selection.Text, 1))
End Sub