Hi, Jezebel,

Larry wants to emulate Word's default behavior -- showing the beginning of
the document's *content*, not the beginning of its name, but only if the
document hasn't already been saved. That makes the job a little more
complicated...

Sub foo()
Dim fn As String, rg As Range
With ActiveDocument
   If (Dir(.Name) <> "") Or (.Words.Count = 1) Then
       fn = .Name
   Else
       Set rg = .Words(1)
       rg.End = .Words(min(9, .Words.Count - 1)).End
       fn = Trim(rg.Text) & ".doc"
       fn = Replace(fn, "\", "")
       fn = Replace(fn, ":", "")
       fn = Replace(fn, """", "")
       fn = Replace(fn, vbCr, "")
       fn = Replace(fn, vbTab, "")
   End If
End With
With Dialogs(wdDialogFileSaveAs)
    .Name = "C:\Documents\tests\" & fn
    .Show
End With
End Sub

Private Function min(a As Long, b As Long)
   min = -((a < b) * a + (a >= b) * b)
End Function

The If statement says that if the document has already been saved at least
once (so that the Dir function returns a non-empty string) or if the
document is blank (because the ever-present final paragraph mark counts as a
"word", you have to test for .Count = 1 instead of 0), then use the current
name. In the case of a blank unsaved file this will be like "Document1".

Otherwise (if the file is unsaved and not blank), the proposed filename will
be the first nine words of the document -- or all the words if there are
fewer than 9. The Replace functions strip out some characters that would be
illegal in a filename.

I'll leave the explanation of the min() function as an exercise for the
interested reader. :-)