Dim pSection as string

pSection = ActiveDocument.Sections(1).Range

john smith was telling us:
john smith nous racontait que :

The easiest way to make this work is to use styles to define the key
paragraphs which are
   "1         Scope of Test"
and
   "2         Assumptions and Constraints"
in your example.

In my example I assume that they are attributed the Style Heading 1. In the
code, replace "wdStyleHeading1" with whatever style you are using.
Also, I included two tests:
The cursor must be placed in a paragraph with that style (or the macro would
not know where to start) and I check for the end of the document to avoid
error messages or endless loops.

'_______________________________________
Sub SelectText()

Dim parCurrent As Paragraph
Dim rgeFinal As Range
Dim lngParCount As Long
Dim lngParIndex As Long

lngParCount = ActiveDocument.Paragraphs.Count
Set parCurrent = Selection.Paragraphs(1)
lngParIndex = ActiveDocument.Range(0, parCurrent.Range.End) _
   .Paragraphs.Count

If parCurrent.Range.Style <> ActiveDocument _
   .Styles(wdStyleHeading1) Then
   MsgBox "You must place the cursor in a pargraph formatted " _
       & "with the style ""Heading 1"".", vbExclamation, _
       "Wrong style"
   Exit Sub
Else
   Set rgeFinal = parCurrent.Range
   Do While lngParIndex < lngParCount
       Set parCurrent = rgeFinal _
           .Paragraphs(rgeFinal.Paragraphs.Count).Next
       lngParIndex = lngParIndex + 1
       If parCurrent.Range.Style <> ActiveDocument _
           .Styles(wdStyleHeading1) Then
           rgeFinal.End = parCurrent.Range.End
       Else
           Exit Do
       End If
   Loop
End If

MsgBox rgeFinal.Text

End Sub
'_______________________________________