Oops.  I forgot to mention the method used one of the For loops to
update the status bar.

Add:
 'Application.StatusBar = ActiveDocument.Paragraphs.Count & "
paragraphs to check. "

Just after the On Error GoTo 0 line.

Also all my test where done with only two or three different
paragraphs repeated many times.  As the number of different paragraphs
increases (in any method I suppose) the time to process will increase.

Hi Greg,

Looks like a derivative of something I developed & posted. My full version is:

Dim SBar As Boolean           ' Status Bar flag
Dim TrkStatus As Boolean      ' Track Changes flag

Sub KillDuplicateParas()
Call MacroEntry
Dim i As Long, j As Long
Dim eTime As Single
eTime = Timer
With ActiveDocument
   If .Paragraphs.Count > 1 Then
       ' Loop backwards to preserve paragraph count & indexing.
       ' Start at 2nd-last paragraph.
       For i = .Paragraphs.Count - 1 To 1 Step -1
           ' Ignore empty paragraphs
           If Len(.Paragraphs(i).Range.Text) > 1 Then
               ' Loop backwards to preserve paragraph count & indexing.
               ' Stop at last preceding paragraph.
               For j = .Paragraphs.Count To i + 1 Step -1
                   ' Report progress on Status Bar.
                   Application.StatusBar = i & " paragraphs to check. "
                   ' No point in checking paragraphs of unequal length.
                   If Len(.Paragraphs(i).Range) = Len(.Paragraphs(j).Range) Then
                       ' Test strings of paragraphs of equal length.
                       If .Paragraphs(i).Range = .Paragraphs(j).Range Then
                           ' Delete duplicate paragraph.
                           .Paragraphs(j).Range.Delete
                       End If
                   End If
               Next
           End If
       Next
   End If
End With
' Report time taken. Elapsed time calculation allows for execution to extend past midnight.
MsgBox "Finished. Elapsed time: " & (Timer - eTime + 86400) Mod 86400 & " seconds."
Call MacroExit
End Sub

Private Sub MacroEntry()
' Store current Status Bar status, then switch on
SBar = Application.DisplayStatusBar
Application.DisplayStatusBar = True
' Store current Track Changes status, then switch off
With ActiveDocument
   TrkStatus = .TrackRevisions
   .TrackRevisions = False
End With
' Turn Off Screen Updating
Application.ScreenUpdating = False
End Sub

Private Sub MacroExit()
' Clear the Status Bar
Application.StatusBar = False
' Restore original Status Bar status
Application.DisplayStatusBar = SBar
' Restore original Track Changes status
ActiveDocument.TrackRevisions = TrkStatus
' Restore Screen Updating
Application.ScreenUpdating = True
End Sub

I think they key difference is that my code checks all paras against each other, whereas yours only checks adjacent paras. I might
incorporate Helmut's revisions, though, since they seem to speed things up a bit.

Cheers

I do that with a wildcard replacement...

Find what: ([!^13]@^13){2,}
Replace with: \1

It's not perfect -- Say

abcd
cd
cd

would be replaced with

abcd

But usually, I just risk that. And it's fast <g>

Klaus