This should show the way...

Sub ResetStyles()
   Dim StyleList As Variant
   Dim i As Long
   Dim oRg As Range
   
   StyleList = Split("Normal,Heading 1,Heading 2", ",")
   
   For i = 0 To UBound(StyleList)
   
       Set oRg = ActiveDocument.Range
       
       With oRg.Find
           .ClearFormatting
           .Text = ""
           .Style = ActiveDocument.Styles(StyleList(i))
           .Format = True
           .Forward = True
           .Wrap = wdFindStop
           .MatchWildcards = False
           
           Do While .Execute
               oRg.Font.Reset
           Loop
       End With
   
   Next
End Sub

Within the first pair of quotes in the Split function, enter a
comma-delimited list of all the style names that you want to reset.
The For loop will cycle through the listed styles, and the Do loop
will reset all occurrences of each style in the main body of the
document.

If you also need to reset styles in textboxes, headers/footers,
footnotes/endnotes, etc. then you need more stuff in your macro.

--
Regards,
Jay Freedman
Microsoft Word MVP        FAQ: http://word.mvps.org
Email cannot be acknowledged; please post all follow-ups to the
newsgroup so all may benefit.