Hi Tony,

Thanks for your reply.

What I'm trying to do is intercept Word's EditFind command and display my
own VBA userform rather than Word's Find dialog. I want my form to be
semi-transparent so that it can remain onscreen but be unobtrusive.

The userform's name is "frmFind". In the EditFind macro that loads the form
I originally used the "normal" way of invoking the form - that is,
"frmFind.Show". However, when I experienced the problem that this posting
relates to I changed the way I invoke the form to see if that would cure it.
The method that I used was to declare an object variable, "MyForm" and use
that to create an instance of the "frmFind" class (Dim MyForm as frmFind ...
Set MyForm = New frmFind). As it happens, this change didn't make any
difference.

The problem that I'm getting is as follows:

If I invoke my form in the VBA IDE, the form displays as semi-transparent
(which is what I want). If I invoke the form outside the IDE by Ctrl+F, or by
Edit/Find, or by going into Tools/Macro/Macros and running the EditFind
macro, the form displays as semi-transparent (good). But if I invoke the form
by clicking a toolbar button (either Word's binoculars icon or a button on a
custom toolbar) the form displays as opaque, not semi-transparent.

The form has a textbox (txtFindText) and three command buttons (cmdFind,
cmdBuiltIn and cmdQuit).

The whole code for the form (which may have changed a little since yesterday
as it's work in progress) is here:

---------------------------------------------------------------------------------------
Option Explicit

Private Const LWA_COLORKEY = &H1
Private Const LWA_ALPHA = &H2
Private Const GWL_EXSTYLE = (-20)
Private Const WS_EX_LAYERED = &H80000

Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
              (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
              (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As
Long) As Long
Private Declare Function SetLayeredWindowAttributes Lib "user32" _
               (ByVal hwnd As Long, ByVal crKey As Long, _
               ByVal bAlpha As Byte, ByVal dwFlags As Long) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
               (ByVal lpClassName As String, ByVal lpWindowName As String)
As Long
Private Declare Function SetWindowPos Lib "user32" _
               (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, _
               ByVal X As Long, ByVal Y As Long, ByVal cx As Long, _
               ByVal cy As Long, ByVal wFlags As Long) As Long

Private Sub cmdBuiltIn_Click()
  Dialogs(wdDialogEditFind).Show
End Sub

Private Sub cmdFind_Click()
   Selection.Find.ClearFormatting
   
   With Selection.Find
       .Text = txtFindText.Text
       .Replacement.Text = ""
       .Forward = True
       .Wrap = wdFindContinue
       .Format = False
       .MatchCase = False
       .MatchWholeWord = False
       .MatchWildcards = False
       .MatchSoundsLike = False
       .MatchAllWordForms = False
   End With
   
   Selection.Find.Execute
   
   txtFindText.SetFocus
End Sub

Private Sub cmdQuit_Click()
  Unload Me
End Sub

Private Sub UserForm_Initialize()
  Dim hwnd As Long
  Dim ret As Long
  Const Transparency As Integer = 128

  hwnd = FindWindow(vbNullString, Me.Caption)
  ret = GetWindowLong(hwnd, GWL_EXSTYLE)
  ret = ret Or WS_EX_LAYERED
  SetWindowLong hwnd, GWL_EXSTYLE, ret
  ret = SetLayeredWindowAttributes(hwnd, 0, Transparency, LWA_ALPHA)
End Su
---------------------------------------------------------------------------------------

The code of the EditFind macro (which has also changed a little) is:

---------------------------------------------------------------------------------------
Sub EditFind()
  Dim MyForm As frmFind
  Const FormTop As Integer = 20
  Const FormLeft As Integer = 600
 
  Set MyForm = New frmFind
  MyForm.Top = FormTop
  MyForm.Left = FormLeft
  MyForm.Show vbModeless
  MyForm.txtFindText.SetFocus
  Set MyForm = Nothing
End Sub
---------------------------------------------------------------------------------------

It's not massively important but it would be nice to know what's happening.

Regards.

Ed