Hi Gil (& Russ).

In addition to Russ's suggestions ...

When you need to work with files and folders there's a very useful
FileSystemObject that you can use. It's very easy to use in VBA.

I think that the "guts" of what you want to do can be done by something like
this code snippet:

-------------------------------------------------------------------
  Set oFSO = CreateObject("Scripting.FileSystemObject")
  Set oFolder = oFSO.GetFolder(SourceFolderPath)

  For Each oFile In oFolder.Files
     FileModifiedDate = Format(oFile.DateLastModified, "yyyymmdd")
     If FileModifiedDate >= StartDate And FileModifiedDate <= EndDate Then
        DestFilePath = oFSO.BuildPath(DestFolderPath, oFile.Name)
        oFile.Move DestFilePath
     End If
  Next
-------------------------------------------------------------------

As you can see, there's not a lot to it. I include below the full code for a
UserForm that has two text boxes which hold the start and end dates and a
command button which initiates the move.

In my case I am using the last modified date of the files
(oFile.DateLastModified) but I could also use the creation date (e.g.
oFile.DateCreated).

Also, in my case I convert the dates to yyyymmdd format to make the
comparison easy but you could probably adapt it to use DateDiff as Russ
suggested.

Most of the rest of the code is validation and stuff.

To get the most benefit from the FileSystemObject, create a reference to
"Microsoft Scripting Runtime" in VBA's Tools>References dialog. That way you
get IntelliSense for it (and also VBA can do some checking for you).

You might have to fix some code lines if they get broken by the
word-wrapping of the newsgroup editor.

The code is:

-------------------------------------------------------------------
Private Sub cmdMove_Click()
  Dim oFSO As Scripting.FileSystemObject
  Dim oFolder As Folder
  Dim oFile As File
  Dim StartDate As String
  Dim EndDate As String
  Dim FileModifiedDate As String
  Dim DestFilePath As String
  Dim Msg As String
  Const SourceFolderPath As String = "C:\Source"
  Const DestFolderPath As String = "C:\Dest"
  Const AppTitle As String = "Move Files"

  On Error GoTo ErrHandler

  If Not DateOK(txtStartDate.Text) Then
     MsgBox "Invalid start date", vbExclamation, AppTitle
     Exit Sub
  End If

  If Not DateOK(txtEndDate.Text) Then
     MsgBox "Invalid end date", vbExclamation, AppTitle
     Exit Sub
  End If

  StartDate = Right(txtStartDate.Text, 4) & Left(txtStartDate.Text, 2) & _
Mid(txtStartDate.Text, 4, 2)
  EndDate = Right(txtEndDate.Text, 4) & Left(txtEndDate.Text, 2) & _
Mid(txtEndDate.Text, 4, 2)

  If StartDate > EndDate Then
     MsgBox "The start date is later than the end date", vbExclamation, _
AppTitle
     Exit Sub
  End If

  Set oFSO = CreateObject("Scripting.FileSystemObject")
  Set oFolder = oFSO.GetFolder(SourceFolderPath)

  For Each oFile In oFolder.Files
     FileModifiedDate = Format(oFile.DateLastModified, "yyyymmdd")
     If FileModifiedDate >= StartDate And FileModifiedDate <= EndDate Then
        DestFilePath = oFSO.BuildPath(DestFolderPath, oFile.Name)
        oFile.Move DestFilePath
     End If
  Next

ExitPoint:
  'Put any cleanup code here
  Exit Sub

ErrHandler:
  Msg = "An error has occurred. Please contact JLawson." & vbCrLf & vbCrLf _
& "Error " & Err.Number & " - " & Err.Description
 
  MsgBox Msg, vbCritical, AppTitle

  Resume ExitPoint
End Sub

Private Function DateOK(DateToCheck As String) As Boolean
  'basic checks - could be beefed up
  If (Not IsDate(DateToCheck)) _
  Or Len(DateToCheck) <> 10 _
  Or Mid(DateToCheck, 3, 1) <> "-" _
  Or Mid(DateToCheck, 6, 1) <> "-" Then
     DateOK = False
     Exit Function
  Else
     DateOK = True
  End If
End Function

Private Sub UserForm_Initialize()
'txtStartDate.Text = "05-06-2007"
'txtEndDate.Text = "12-10-2007"
End Sub
-------------------------------------------------------------------

Regards.

Ed