Hi Francis

The following will find the first cell in column E that contains the text of
interest. It assumes that the table is entirely regular, with no merged
cells. You'll need to add error checking appropriate to the circumstances.

Sub FindAStringInColumnE()

Dim oTable As Word.Table
Dim colE As Word.Column
Dim oCell As Word.Cell
Dim lngRowWeFound As Long
Dim sMyText As String

   'Get a reference to our table
   Set oTable = Selection.Tables(1)

   'Identify the text we want to find
   sMyText = "D02-001"

   'Identify the column to search
   Set colE = oTable.Columns(5)

   'Go through each cell in our column...
   For Each oCell In colE.Cells

       'See if our text is found in that cell
       If InStr(1, oCell.Range.Text, sMyText, vbTextCompare) > 0 Then

           'If it's found, then record the row where
           'we found our text
           lngRowWeFound = oCell.RowIndex

           'quit while we're ahead!
           Exit For
       End If
   Next oCell

   If lngRowWeFound > 0 Then
       MsgBox "We found " & sMyText & " in row " & CStr(lngRowWeFound)
   Else
       MsgBox "We could not find " & sMyText & " in the table"
   End If

End Sub

Hope this helps.

Shauna Kelly.  Microsoft MVP.
http://www.shaunakelly.com/word