Jerem,
I stumbled upon hyperlinks tonight and thought of your question about
formatting crossreferences to be underlined, etc.
What you probably remembered and intended to use, was not literally a
crossreference field with {REF...} but a hyperlink field with a small ell as
a switch to link to a bookmark within a document. { HYPERLINK \l "Test"}
Where "Test" is a name of a bookmark. A hyperlink will look underlined by
default.

A REF field just gives the starting jump-point text a gray background by
default, which doesn't show when printing.

Underlined hyperlinks do show when printing.

I wrote this subroutine to create a hyperlink out of selected text to a
bookmark within the current document. It then stores a couple of parameters
in document variables to use as default values when asking for input the
next time. To use subroutine, you must have bookmarks already in document.
Insertion point or selected text will be made into a hyperlink.

Sub InsertHyperlinkToBookmark()
Dim strBookMarkName As String
Dim strScreenTip As String
Dim strTextToDisplay As String
Dim aVar As Word.Variable
Dim num As Long
Dim myVar As String
Dim aRange As Word.Range
Dim strPrompt As String

If ActiveDocument.Bookmarks.Count = 0 Then
   MsgBox "Insert some bookmarks, first."
   Exit Sub
End If

strPrompt = "Bookmark To Jump To:" & vbCr & _
   vbCr & "If left blank then bookmark list will appear." & vbCr & _
   "A. Pick a bookmark from list" & vbCr & _
   "B. Choose Goto button." & vbCr & _
   "C. Choose Close button."

num = 0
For Each aVar In ActiveDocument.Variables
   If aVar.Name = "BookMarkName" Then
       num = aVar.Index
       Exit For
   End If
Next aVar
If num = 0 Then
   strBookMarkName = InputBox(strPrompt, _
       "What is the Bookmark Name?")
   If strBookMarkName = "" Then
       Set aRange = Selection.Range
       With Dialogs(wdDialogInsertBookmark)
          .Display
          strBookMarkName = .Name
       End With
       aRange.Select
   End If
   ActiveDocument.Variables.Add Name:="BookMarkName", _
       Value:=strBookMarkName
Else
   strBookMarkName = Trim(InputBox(strPrompt, _
       "What is the Bookmark Name?", _
       ActiveDocument.Variables("BookMarkName").Value))
    If strBookMarkName = "" Then
       Set aRange = Selection.Range
       With Dialogs(wdDialogInsertBookmark)
          .Display
          strBookMarkName = .Name
       End With
       aRange.Select
   End If
  ActiveDocument.Variables("BookMarkName").Value = strBookMarkName
End If

num = 0
For Each aVar In ActiveDocument.Variables
   If aVar.Name = "ScreenTip" Then
       num = aVar.Index
       Exit For
   End If
Next aVar
If num = 0 Then
   strScreenTip = InputBox("ScreenTip:" & vbCr & _
       "If blank of Cancel, then it will be bookmark name.", _
       "What is the ScreenTip?", Trim(Selection.Range))
   ActiveDocument.Variables.Add Name:="ScreenTip", Value:=strScreenTip
Else
   strScreenTip = InputBox("ScreenTip:" & vbCr & _
       "If blank of Cancel, then it will be bookmark name.", _
        "What is the ScreenTip?", _
       ActiveDocument.Variables("ScreenTip").Value)
   ActiveDocument.Variables("ScreenTip").Value = strScreenTip
End If

strTextToDisplay = InputBox("Text To Display:" & vbCr & _
   "Cancel or blank will be selected text." & vbCr & _
   "Or if just insertion point, it will be bookmark name.", _
    "What is the Text to Display?", Trim(Selection.Range))

ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, _
   SubAddress:=strBookMarkName, ScreenTip:=strScreenTip, _
   TextToDisplay:=Trim(strTextToDisplay)

'Hyperlink arguments are:
'Anchor - Required Object. The text or graphic that you want turned into a _
   hyperlink.
'Address - Optional Variant. The address for the link. The address can be _
   an e-mail address, an Internet address, or a file name. Note that Word _
   doesn't check the accuracy of the address.
'SubAddress - Optional Variant. The name of a location within the _
   destination file, such as a bookmark, named range, or slide number.
'ScreenTip - Optional Variant. The text that appears as a screen tip when _
   the mouse pointer is positioned over the specified hyperlink. The _
   default value is Address.
'TextToDisplay - Optional Variant. The display text of the specified _
   hyperlink. The value of this argument replaces the text or graphic _
   specified by Anchor.
'Target - Optional Variant. The name of the frame or window in which you _
   want to load the specified hyperlink.

End Sub