Hi Brian

Try this....

Sub delTables()

Dim nCounter As Long
Dim nNumTables As Long
Dim oTable As Word.Table

   'Find out how many tables there are
   nNumTables = ActiveDocument.Tables.Count

   'Start at the last table, and work backwards
   'through the tables in the document.
   'We do this because we are deleting tables,
   'and the index would go awry as we cycled
   'through them.
   For nCounter = nNumTables To 1 Step -1

       'Get a reference to this table
       Set oTable = ActiveDocument.Tables(nCounter)

       'If the table has 2 columns...
       If oTable.Columns.Count = 2 Then
           '...delete it
           oTable.Delete
       End If

   Next nCounter

End Sub

Hope this helps.

Shauna Kelly.  Microsoft MVP.
http://www.shaunakelly.com/word

This is from VBA Help for the columns collection:
MsgBox ActiveDocument.Tables(1).Columns.Count
Or in your case

Sub delTables()
Dim oTbl As Table
'If ActiveDocument.Tables.Count >= 1 Then
For Each oTbl In ActiveDocument.Tables
   If oTbl.Columns.Count = 2 then
   oTbl.Delete
   ' or oTbl.Range.Delete
  End If
Next oTbl
'End If
End Sub