Tery,
Glad you got it working.
Although, it seems curious that in your code you are changing the first
instance of the word 'running' to a '}' character?

And it looks like you didn't want to move the found text to the very
beginning of the document, but maybe after the first paragraph along with a
couple of empty paragraphs, afterwards, for spacing?

That is easily tweaked by using these changes:
'========================
Sub Move_Running_To_Top()
Dim aRange As Word.Range
Set aRange = ActiveDocument.Content

With aRange.Find
   .Text = "Device[!^13]@running*\nend[^13 ]{1,}" 'space character included
   .MatchWildcards = True
   While .Execute
       ActiveDocument.Paragraphs(1).Range.InsertAfter aRange.Text _
           & vbCr & vbCr
       aRange.Delete
   Wend
End With
End Sub
'========================
To insert found text in the same order that it was found, I made this
adjustment:
'========================
Sub Move_Running_To_Top2()
Dim aRange As Word.Range
Dim aRange2 As Word.Range

Set aRange = ActiveDocument.Content
Set aRange2 = ActiveDocument.Paragraphs(1).Range

With aRange.Find
   .Text = "Device[!^13]@running*\nend[^13 ]{1,}" 'space character included
   .MatchWildcards = True
   While .Execute
       aRange2.InsertAfter aRange.Text & vbCr & vbCr
       aRange2.Collapse direction:=wdCollapseEnd
       aRange.Delete
   Wend
End With
End Sub
'========================
I try to use the Range object, rather than the Selection object for speed.
So my code automatically moves everything to the top. Did you want to
**manually** select only certain devices that are running to move to the
top?

P.S.
I unintentionally left a \n in my original code posting because in MacWord I
have to use that instead of any ^13. So if it causes no problems in WinWord,
then ignore it, otherwise change the \n to a ^13 in the wildcard search
strings.