Delete the text first, and then merge the cells:

Sub MergeRangeAndRemoveText()

Dim rng As Range
Dim i As Long, j As Long

For i = 5 To 6
   For j = 3 To 5
       ActiveDocument.Tables(1).Cell(Row:=i, Column:=j). _
           Range.Text = ""
   Next j
Next i

Set rng = ActiveDocument.Range _
   (Start:=ActiveDocument.Tables(1).Cell(5, 3).Range.Start, _
   End:=ActiveDocument.Tables(1).Cell(6, 5).Range.End)

rng.Cells.Merge

End Sub

FWIW, working with ranges and table columns is tricky. The following code,
used on a document that has a table with at least six rows and more than
five columns, illustrates the problem:

Set rng = ActiveDocument.Range _
   (Start:=ActiveDocument.Tables(1).Cell(5, 3).Range.Start, _
   End:=ActiveDocument.Tables(1).Cell(6, 5).Range.End)

rng.Select

rng.Font.Bold = True
Selection.Font.Name = "Courier New"

Note which cells will be bold and which will be in Courier New!

Very interesting. It 'works' in Word 2007, but not in 2003. I didn't know
there had been a change in behaviour.

The Range you define includes cells (5,3), (5,4), (5,5), ..., (5, last) ,
(6,1), (6,2), ..., (6,5)

If you Select it (rng.Select) then just the block (5,3), (5,4), (5,5),
(6,3), (6,4), (6,5) is selected and it is this block that is merged - as you
already know.

After the merge the Range appears to be redefined (in 2003) which is why the
text in the merged cell is not deleted.

If you redefine it yourself you will be able to delete the text.

   Sub MergeRangeAndRemoveText2()
       Dim rng As Range

       Set rng = ActiveDocument.Range _
       (Start:=ActiveDocument.Tables(1).Cell(5, 3).Range.Start, _
       End:=ActiveDocument.Tables(1).Cell(6, 5).Range.End)

       rng.Cells.Merge

       Set rng = ActiveDocument.Range _
       (Start:=ActiveDocument.Tables(1).Cell(5, 3).Range.Start, _
       End:=ActiveDocument.Tables(1).Cell(5, 3).Range.End)

       rng.Text = ""
   End Sub

Hi Tony and Stefan
I should have mentioned I'm using Word 2003.

Thank you both for two working solutions.

I appreciate the help.

Harold

Hi All
I cannot merge a cell at row 1, column 1
with a cell at row 2, column 1 using a range object.
I can only merge those two cells using selection method.

****************************************************
Dim rng As Range

Set rng = ActiveDocument.Range _

(Start:=ActiveDocument.Tables(1).Cell(1, 1).Range.Start, _
End:=ActiveDocument.Tables(1).Cell(2, 1).Range.End)

rng.Cells.Merge
****************************************************
Just curious
Harold