You cannot use the simple Replace/Find in this case. Since you want to
target tables inside textboxes, you need more code. And it will take some
time to execute depending on the document content.

Here is some code to get you going:

Option Explicit

Sub test()

Dim docMain As Document
Dim rngTable As Range
Dim i As Long
Dim j As Long

Set docMain = ActiveDocument

With docMain
   If .Shapes.Count > 0 Then
       For i = 1 To .Shapes.Count
           With .Shapes(i)
               If .Type = msoTextBox Then
                   If .TextFrame.HasText Then
                       With .TextFrame.TextRange.Tables
                           If .Count > 0 Then
                               For j = 1 To .Count
                                   Set rngTable = .Item(j).Range
                                   With rngTable.Find
                                       .Text = "cat"
                                       .Replacement.Text = "Bird"
                                       .Execute Replace:=wdReplaceAll
                                   End With
                               Next
                           End If
                       End With
                   End If
               End If
           End With
       Next
   End If
End With

End Sub