Greg,

Thanks for catching my mistake. Once again I was in a rush to get the post
out and didn't look closely enough at what I was writing and reversed the
order of the arguments. My bad. As the LTSA is always telling us, "The faster
you go, the bigger the mess." :-D

As for the process used for actualling inserting the TextBox value, I would
agree completely. In fact, this is what I usually do - use the TextBox value
in the .Text property of the Range and then wrap the bookmark around the
Range again. However, Jeri used the .InsertBefore method in the original
post, so I decided to just stick with that.

I would also avoid using the ActiveDocument object and instead reference a
specific Document object, similar to the following:

Private Sub InsertTextBoxValue(BookmarkName As String, TextBoxValue As  
String)
Dim myDoc as Document
Dim myRange As Range
    Set myDoc = ActiveDocument
    Set myRange = myDoc.Bookmarks(BookmarkName).Range
    myRange.Text = TextBoxValue
    myDoc.Bookmarks.Add BookmarkName, myRange
End Sub

However, I would probably declare the Document object in the general
declarations and set it to the ActiveDocument well before I ever got to my
InsertTextBoxValue procedure - most likely in the AutoNew procedure. I would
also do the same with a UserForm object for UserForm1 and write some code to
collect the various TextBox values without relying on the existence of the
object itself.

I left this out of my original post to save Jeri from being overwhelmed, but
since we've come this far...

Assuming the following:
- A main module called Module1
- A UserForm called UserForm1
- Four TextBoxes on the UserForm for collecting information
- Two CommandButtons on the UserForm; one for creating the document and one
to cancel it.
- Four bookmarks in the document named in accordance with Jeri's original post

In Module1 I would place the following code:

Option Explicit

Public bNewDoc As Boolean
Dim myDoc As Document
Dim myForm As UserForm1
Dim TextBox1Value As String
Dim TextBox2Value As String
Dim TextBox3Value As String
Dim TextBox4Value As String

Sub AutoNew()
   Set myDoc = ActiveDocument
   Set myForm = New UserForm1
   Load myForm
   myForm.Show
   If bNewDoc = True Then CollectValues
   Unload myForm
   Set myForm = Nothing
   If bNewDoc Then InsertValues Else myDoc.Close wdDoNotSaveChanges
End Sub

Private Sub CollectValues()
   With myForm
       TextBox1Value = .TextBox1.Value
       TextBox2Value = .TextBox2.Value
       TextBox3Value = .TextBox3.Value
       TextBox4Value = .TextBox4.Value
   End With
End Sub

Private Sub InsertValues()
   InsertTextBoxValue "RecipientName", TextBox1Value
   InsertTextBoxValue "RecipientReturnAddress", TextBox2Value
   InsertTextBoxValue "RecipientCSZ", TextBox3Value
   InsertTextBoxValue "ReferenceNo", TextBox4Value
End Sub

Private Sub InsertTextBoxValue(BookmarkName As String, TextBoxValue As String)
   With myDoc
       If .Bookmarks.Exists(BookmarkName) Then
       Dim myRange As Range
           Set myRange = .Bookmarks(BookmarkName).Range
           myRange.Text = TextBoxValue
           .Bookmarks.Add BookmarkName, myRange
       Else: MsgBox "Bookmark " & BookmarkName & "not found."
       End If
    End With
End Sub

And in UserForm1:

Option Explicit

Private Sub UserForm_Initialize()
   bNewDoc = False
End Sub

Private Sub CommandButton1_Click()
   bNewDoc = True
   Me.Hide
End Sub

Private Sub CommandButton2_Click()
   bNewDoc = False
   Me.Hide
End Sub

Even this is stripped down a bit. For instance, there is nothing in the
UserForm1 code to ensure that all values have been entered or to format the
values if necessary, etc., and the error handling is minimal elsewhere as
well. However, it's more than sufficient for the purpose of answering Jeri's
question. (And I even tested it to make sure it works! ;-P)

Jeri, if you would like me to explain what I've done in more detail, feel
free to contact me at the email address in my profile. I'll send you a
commented version of my test template for you to pick apart.

[Lines deleted to for readability]