Well, this is the word.VBA.general group. Questions about automating
Word from outside VBA are often posted to the word.programming group,
but there's certainly no enforceable rule.

You're correct about losing non-default formatting from the existing
picture, and that would happen in VBA as well -- I thought you were
concerned about losing the content control.

I don't see any alternative to copying the properties. Write it as a
separate subroutine, and once the work is done you just need to call
it as needed.

Getting the rotation of a picture in a content control is unreasonably
difficult. A picture in the control is an InlineShape, and in the
object model that type doesn't include a Rotation member. (This is a
case of VBA's object model lagging behind changes in the user
interface; in earlier versions you couldn't rotate an inline picture.)
VBA won't let you convert the InlineShape to a Shape. You have to copy
the picture and paste it to a place outside the content control, where
it can be converted to a Shape to get its Rotation value. Try this:

Sub z()
   Dim oPic As InlineShape
   Dim oShp As Shape
   Dim oRg1 As Range, oRg2 As Range
   Dim rot As Single
   
   Set oPic = ActiveDocument.ContentControls(1) _
       .Range.InlineShapes(1)
   Set oRg1 = oPic.Range
   
   ' get a range outside the content control
   Set oRg2 = ActiveDocument.ContentControls(1).Range
   oRg2.Collapse wdCollapseEnd
   oRg2.Move wdCharacter, 1
   
   ' copy the picture from the control and
   ' paste it outside the control
   oRg1.Copy
   oRg2.Paste
   
   ' make it a shape and find its rotation
   Set oShp = oRg2.InlineShapes(1).ConvertToShape
   rot = oShp.Rotation
   
   ' get rid of the leftovers
   oShp.Delete
   oPic.Delete
   
   ' put the new picture in the control
   ' and rotate it
   Set oShp = ActiveDocument.Shapes.AddPicture _
       (FileName:="c:\temp\jay headshot.jpg", _
       Anchor:=oRg1)
   oShp.Rotation = rot
End Sub