Here's three variations that should give you some ideas / get you started ...

Sub AddPagesToDoc()

   Dim doc1 As Document
   Dim doc2 As Document
   Dim rng As Range
   
   Set doc1 = Documents.Open("c:\temp\testdoc.doc")
   
   Set rng = doc1.Range
   
   With rng
       
       'position insertion point at
       'end of document
       .Collapse wdCollapseEnd
       
       'insert a page break
       .InsertBreak Type:=wdPageBreak
       
       'insert a section break
       .InsertBreak Type:=wdSectionBreakNextPage
       
   End With
   
   doc1.Close wdDoNotSaveChanges
   
   Set doc1 = Nothing

End Sub

Sub CopyTextToEndOfNewDoc()

   Dim doc1 As Document
   Dim doc2 As Document
   Dim rng As Range
   
   Set doc1 = Documents.Open("c:\temp\doc1.doc")
   Set doc2 = Documents.Open("c:\temp\doc2.doc")
   
   Set rng = doc2.Range
   
   With rng
       
       'position insertion point at
       'end of document
       .Collapse wdCollapseEnd
       
       'insert a page break
       .InsertBreak Type:=wdPageBreak
       
       .Text = doc1.Range.Text
       
   End With
   
   doc1.Close wdDoNotSaveChanges
   doc2.Close wdSaveChanges
   
   Set doc1 = Nothing
   Set doc2 = Nothing

End Sub

Sub InsertDoc1AtEndDoc2()
   Dim doc1 As Document

   Dim doc2 As Document
   Dim rng As Range
   
   Set doc2 = Documents.Open("c:\temp\doc2.doc")
   
   Set rng = doc2.Range
   
   With rng
       
       'position insertion point at
       'end of document
       .Collapse wdCollapseEnd
       
       'insert a page break
       .InsertBreak Type:=wdPageBreak
       
   End With
   
   'insert doc1 at the insertion point
   'you just created with the rng object
   rng.InsertFile _
       FileName:="doc1.doc", _
       Range:="", _
       ConfirmConversions:=True, _
       Link:=False, _
       Attachment:=False

   doc2.Close wdSaveChanges
   
   Set doc2 = Nothing

End Sub