Hi Steve,

not quite simple.
I'm assuming, that you want all characters
before the first parenthesis to be bold,
and that there is no other text,
to which the definition in the search patterns would apply.

Sub RaceBaseBold2()
Dim rDcm As Range
Dim rTmp As Range
Set rDcm = ActiveDocument.Range
ResetSearch
  With rDcm.Find
     .Text = "[A-Za-z]{1,}\([0-9 ]{2,}\)"
     .MatchWildcards = True
     While .Execute
        Set rTmp = rDcm
        With rTmp.Find
           .Text = "[A-Za-z]{1,}"
           If .Execute Then
              rTmp.Font.Bold = True
           End If
        End With
        rDcm.Collapse direction:=wdCollapseEnd
        rDcm.End = ActiveDocument.Range.End
        .Text = "[A-Za-z]{1,}\([0-9 ]{2,}\)"
     Wend
  End With
ResetSearch
End Sub

Public Sub ResetSearch()
With Selection.Find
  .ClearFormatting
  .Replacement.ClearFormatting
  .Text = ""
  .Replacement.Text = ""
  .Forward = True
  .Wrap = wdFindContinue
  .Format = False
  .MatchCase = False
  .MatchWholeWord = False
  .MatchWildcards = False
  .MatchSoundsLike = False
  .MatchAllWordForms = False
  ' plus some more if needed
  .Execute
End With
End Sub

Greetings from Bavaria, Germany

Helmut Weber, MVP, WordVBA

Win XP, Office 2003
"red.sys" & Chr$(64) & "t-online.de"